#!/bin/csh -f
#-----------------------------------------------------------------------------
if ($#argv < 1) then
    echo 'Usage: runon nodename ... (at least one nodename required)'
    exit 1
endif
#-----------------------------------------------------------------------------
# You need to customize feddir and fedexec if necessary.
# Shared file system is assumed (i.e., same file location on all nodes).
#-----------------------------------------------------------------------------
set ARCH = LINUX
set FMTYPE = MIX
set feddir = `pwd`
set fedexec = OBJ/${ARCH}/${FMTYPE}/tm_ping

#-----------------------------------------------------------------------------
if (${ARCH} == "SPARC") then
    set fedexec = "/usr/proc/bin/ptime $fedexec"
    echo '-------------------------------------------------------------------'
    echo Running federates under ptime control to enable hi-res timer support
    echo '-------------------------------------------------------------------'
endif

#-----------------------------------------------------------------------------

set sessionname = ID.$$    #needs to be unique across runs, so use process ID
set numnodes = $#argv
set info = $numnodes':'$argv[1]
foreach i ($argv[2-])
    set info = $info','$i
end

set j = 0
foreach i ($argv[1-])
    set nodeinfo = $info':'$j
    set cmd = "ssh $i ""(setenv NETINFOFILE ./netinfo.fdk; setenv LD_LIBRARY_PATH ../../LIB; setenv TMDEBUG 0; setenv RMDEBUG 0; setenv SHMFMDEBUG 1; setenv GMFMDEBUG 1; setenv MIXFMDEBUG 1; setenv SESSIONNAME $sessionname; setenv NODEINFO $nodeinfo; cd $feddir; $fedexec 100000 |& tee /tmp/`whoami`-tmping-$FMTYPE-$j-$numnodes.out)"""
    echo $cmd
    $cmd &
    @ j =$j + 1
end
#-----------------------------------------------------------------------------