// Terrain viewer
// Written by Jarek Rossignac August 2007
// for the scientific visualizatoin class
// Loads a 64x64 terrain from file 
// Shades it either using color computed from height or using a texture with iso-level lines
// Provides a tool for picking a vertex and changing its height
import processing.opengl.*;                // comment out if not using OpenGL
PImage myImage;                            // image used as tecture 

int n=64;                                   // size of grid. Must be >2!
pt[][] G = new pt [n][n];                   // array of vertices
vec[][] L = new vec [n][n];                 // laplace vectors for smoothing
int pi=2,pj=2;                              // indices of vertex being dragged when mouse is pressed
pt Mouse = new pt(0,0,0);                   // current mouse position
boolean showLight=true;                      // flags to toggle the light
color red = color(200, 10, 10), blue = color(10, 10, 200), green = color(10, 200, 20), yellow = color(250, 250, 100), magenta = color(200, 50, 200), black = color(10, 10, 10); 
float w,h,ww,hh;                             // width, height of cell in absolute and normalized units
vec offset = new vec (0,0,0);                // offset vector from mouse to clicked vertex
float ax=342, az=1557;                          // camera angles 
float zmax=10, zmin=0;
String [] S= new String [n*n+1];
boolean pick=false;                          // semaphor to render once for picking
boolean showEdges=false;                    // toggle to show edges
boolean useTexture=true;                    // toggle to show edges
boolean showMenu=true;
boolean showImage=false;
boolean colors=true;
color cc = green;                            // color for picking
float r=100;                                // square of the radius of the Region of Influence
int showROI=0;
int fn=1, fnm=4;
float waterLevel = 5;

// ** SETUP **
void setup() { size(800, 800, OPENGL);                              //for OpenGL use: void setup() { size(800, 800, OPENGL);  
  PFont font = loadFont("Courier-14.vlw"); textFont(font, 12);      // load font for writing on window
  myImage = loadImage("ramp.jpg");                                 // load image for texture of level curves
  ww=1.0/(n-1); hh=1.0/(n-1);                                      // set intial width and height of a cell
  w=width*ww; h=height*hh;                                         // set intial width and height of a cell in normalized [0,1]x[0,1]
  resetVertices();
  S=loadStrings("F0.hts"); hFromString(); 
  } 
 
void resetVertices() { for (int i=0; i<n; i++) for (int j=0; j<n; j++) G[i][j]=new pt(i*w,j*h,0);  } 
 
// ** DRAW **
void draw() { background(101,102,103); 
sphereDetail(6); 
  if (showMenu) {displayMenu(); return;};
  translate(width/2,height/2,-150);
  rotateX(PI/2.-ax*PI/height/2.);
  rotateZ(-az*PI/width/4.);
  translate(-width/2,-height/2,0);  
  if (pick) { pick=false;  paintToPick(); cc = get(mouseX,height-mouseY); int ppi=int(red(cc)); int ppj=int(green(cc)); 
              if ((ppi>=0) && (ppi<n) && (ppj>=0) && (ppj<n) ) {pi=ppi; pj=ppj; }; } ;
  if  (mousePressed) {
    if ((keyPressed)&&(key=='w')) {waterLevel-=(mouseY-pmouseY)*(zmax-zmin)/height; }
    if ((keyPressed)&&(key=='z')) {G[pi][pj].z-=mouseY-pmouseY; XYcubicFilter();}
    if (!keyPressed)  {ax+=mouseY-pmouseY;  az+=mouseX-pmouseX;}  
        
    };
  if (showLight) lights(); 
  if (showImage) scale(1,1,0); 
  if (useTexture) paintTexturedTerrain(); else  paintTerrain(); 
  if (showEdges) {noFill(); stroke(black); drawEdges(); };    
  noStroke(); fill(red);  G[pi][pj].show(5); 
  if (showROI>0) {showROI--; fill(red,80); G[pi][pj].show(sqrt(r)*w); };
  translate(0,0,waterLevel); fill(blue,80); rect(0,0,n*w,n*h);
   };
  
void paintTexturedTerrain() {          // renders the terrain using the texture with level lines
   noStroke(); fill(255); textureMode(NORMALIZED);       // texture parameters in [0,1]x[0,1]
   beginShape(QUADS); 
   for (int i=0; i<n-1; i++) {
     beginShape(QUAD_STRIP); texture(myImage); 
     for (int j=0; j<n; j++) { 
    float zi=(G[i][j].z-zmin)/(zmax-zmin), zip=(G[i+1][j].z-zmin)/(zmax-zmin);
        G[i][j].vertext(0.5,zi);  G[i+1][j].vertext(0.5,zip); };
     endShape();
     };
   }

void paintTerrain() {         // renders the terrain with color as a function of height
   noStroke(); fill(255);        
   beginShape(QUADS); 
   for (int i=0; i<n-1; i++) {
     beginShape(QUAD_STRIP); 
     for (int j=0; j<n; j++) { 
           float zi=(G[i][j].z-zmin)/(zmax-zmin), zip=(G[i+1][j].z-zmin)/(zmax-zmin); 
//           fill(sq(sq(1.-abs(0.5-zi)))*200,(1.-zi)*256,zi*256);
     if (colors)      fill(zi*256 ,(1.-zi)*256, sq(sq(1.-abs(0.5-zi)))*200 ); else fill(zi*256,zi*256,zi*256);
           G[i][j].vert();  G[i+1][j].vert(); 
         };
     endShape();
     };
   }

void paintImage() {         // renders the terrain with color as a function of height
   noStroke(); fill(255);        
   beginShape(QUADS); 
   for (int i=0; i<n-1; i++) {
     beginShape(QUAD_STRIP); 
     for (int j=0; j<n; j++) { 
           float zi=(G[i][j].z-zmin)/(zmax-zmin), zip=(G[i+1][j].z-zmin)/(zmax-zmin); 
//           fill(sq(sq(1.-abs(0.5-zi)))*200,(1.-zi)*256,zi*256);
           fill(zi*256 ,(1.-zi)*256, sq(sq(1.-abs(0.5-zi)))*200 );
           G[i][j].vert2d();  G[i+1][j].vert2d(); 
         };
     endShape();
     };
   }

void paintToPick() {           // Paints a rectangle around each vertex using a color computed from the vertex indices
   noStroke(); 
   for (int i=1; i<n-1; i++) for (int j=1; j<n-1; j++) { 
     fill(i,j,0); 
     beginShape();   
     average(G[i-1][j-1],G[i][j-1],G[i-1][j],G[i][j]).vert();  
     average(G[i-1][j+1],G[i][j+1],G[i-1][j],G[i][j]).vert();  
     average(G[i+1][j+1],G[i][j+1],G[i+1][j],G[i][j]).vert();  
     average(G[i+1][j-1],G[i][j-1],G[i+1][j],G[i][j]).vert();       
     endShape();
     };
   }

void setLimits() { 
  zmin=100000;  zmax=-100000;
     for (int i=0; i<n-1; i++) for (int j=0; j<n; j++) {if(G[i][j].z<zmin) zmin=G[i][j].z;  if(G[i][j].z>zmax) zmax=G[i][j].z; };
  }
  
void drawEdges() {            // draws the edges between neighboring vertices
   stroke(black); noFill(); 
   beginShape(QUADS); 
   for (int i=0; i<n-1; i++) {
      beginShape(QUAD_STRIP); texture(myImage); 
      for (int j=0; j<n; j++) { G[i][j].vert(); G[i+1][j].vert(); };
      endShape();
      };
   }


//**********************************
//***      GUI ACTIONS
//**********************************

void keyPressed() {  
   if (key=='0') resetVertices();
   if (key=='s') setLimits();
   if (key=='i') showImage=!showImage;
   if (key=='c') colors=!colors;
   if (key=='l') showLight=!showLight;
   if (key=='t') useTexture=!useTexture;
   if (key=='e') showEdges=!showEdges;
   if (key=='I') {String SP=" "+"-####.tif"; saveFrame(SP);};  
   if (key=='W') {String F="F"+str(fnm)+".hts"; hToString(); saveStrings(F,S); fnm++;};
   if (key=='R') {String F="F"+str(fn)+".hts"; S=loadStrings(F); hFromString(); fn=(fn+1)%fnm; };
   if (key==' ') showMenu=!showMenu;
   if (key=='f') {XYcubicFilter();};
   if (key==',') {r/=2; showROI=5;} if (key=='.') {r*=2; showROI=5;}
  };
 
void mousePressed() {if ((keyPressed)&&(key=='z')) {pick=true; showROI=3;};}
 
void hToString() {
   int k=0; S[k]=str(n);
   for (int i=0; i<n; i++) for (int j=0; j<n;j++) {k++; S[k]=str(G[i][j].z);};
   }

void hFromString() {
   int k=0; n=int(S[k]);
   for (int i=0; i<n; i++) for (int j=0; j<n;j++) {k++;  G[i][j].z=float(S[k]); };
   setLimits();
   } 

void pickClosestProjectionVertex() {
  float minDist=2*w;
  for (int i=0; i<n; i++) for (int j=0; j<n; j++) {
    float dist =sqrt(sq(screenX(G[i][j].x,G[i][j].y,G[i][j].z)-mouseX)+sq(screenY(G[i][j].x,G[i][j].y,G[i][j].z)-mouseY));
    if (dist<minDist) {minDist=dist; pi=i; pj=j;};
    };
  }    
  
void displayMenu() {
    pushMatrix(); fill(yellow);
    translate(100,50,150);
    text("TERRAIN VIEWER/EDITOR by Jarek Rossignac",0,0); translate(0,20);
    text("",0,0); translate(0,30);
    text("Click in the window to activate it",0,0); translate(0,30);
    text("Press SPACE BAR to hide/show this menu",0,0); translate(0,20);
    text("Click&drag to rotate view",0,0); translate(0,30);
    text("'l' turns light on/off",0,0); translate(0,30);
    text("'e' toggles between showing/hiding the edges",0,0); translate(0,30);
    text("'t' toggles between using color or texture with iso-level curves",0,0); translate(0,30);   
    text("'c' toggles between using 3 color ranges or just intensity",0,0); translate(0,30);
    text("'i' toggles between showing a flat image or a 3D terain",0,0); translate(0,30);    
    text("keep 'z' pressed, click&drag up/down to edit and smoothen terrain",0,0); translate(0,30);
    text("keep 'w' pressed, click&drag up/down to edit the water height",0,0); translate(0,30);
    text("',' and '.' change the radius of the region of influence for smoothing",0,0); translate(0,30);
    text("'R' reads the next dataset",0,0); translate(0,30);
    text("'s' re-normalizes the height range",0,0); translate(0,30);
    text("THE FOLLOWING DO NOT WORK FROM A WEB BROWSER. (ONLY WHEN RUNNING LOCAL.)",0,0); translate(0,30);
    text("'W' saves terrain to file (over-writes old data). Not in a browser.",0,0); translate(0,30);
    text("'I' saves a file with a picture of the screen.",0,0); translate(0,30);
    popMatrix();
   }
   
// **********************************
// ***      smoothing
// **********************************
 // 0: average of x and y cubics

void XYcubicFilter() {
   for(int k=0; k<20; k++) {
    for (int i=2; i<n-2; i++) for (int j=2; j<n-2; j++) L[i][j]=average(cubicFitX(i,j),cubicFitY(i,j));
    for (int i=2; i<n-2; i++) for (int j=2; j<n-2; j++) if (sq(i-pi)+sq(j-pj)<r) if((i!=pi)||(j!=pj)) G[i][j].addScaledVec(0.5,L[i][j]); 
   };
  }

vec cubicFitX(int i, int j) {return(cubic(G[i-2][j], G[i-1][j],G[i][j],G[i+1][j],G[i+2][j] ));}
vec cubicFitY(int i, int j) {return(cubic(G[i][j-2], G[i][j-1],G[i][j],G[i][j+1],G[i][j+2] ));}
vec cubic (pt A, pt B, pt C, pt D, pt E) 
    {return(new vec( (-A.x+4*B.x-6*C.x+4*D.x-E.x)/6, (-A.y+4*B.y-6*C.y+4*D.y-E.y)/6, (-A.z+4*B.z-6*C.z+4*D.z-E.z)/6  ));}