// car accidents
// Written June 2006 by Jarek Rossignac

color red=color(256,100,100), green=color(100,256,100), blue=color(100,100,256), yellow=color(256,230,100), grey=color(100,100,100);
int nr=6; car C [] = new car [nr];
int ns=6; street S [] = new street [ns];
vec I=new vec (1,0);

class street {
  float w=80;                                      // street width
  pt B=new pt(700,100), F=new pt(600,700);         // front and back end-points
  boolean pickedB=false, pickedF=false, picked=false;
  street (float bx, float by, float fx, float fy, float pw) {B.x=bx; B.y=by; F.x=fx; F.y=fy; w=pw;};
  void paint() {fill(200,200,100); noStroke(); 
    vec N=B.vecTo(F).left(); N.unit(); N.mul(w);
    beginShape(); B.movedBy(N).vert();  F.movedBy(N).vert(); N.back(); F.movedBy(N).vert(); B.movedBy(N).vert();  endShape();
    };
  void paintLine() {B.showLineTo(F); };
  boolean selected() {
    pickedF = F.vecTo(mouse()).norm()<30; 
    pickedB = B.vecTo(mouse()).norm()<30; 
    picked=pickedF||pickedB; return(picked); }
  void track() {pt M=mouse(); if(pickedF) {F.setTo(M);} if(pickedB) {B.setTo(M);} }
  void paintDots() {if (!pickedB) {fill(yellow); B.show(20);};  if (!pickedF) {fill(yellow); F.show(20); }; };
  void snap() {
    if (pickedB) {if(abs(B.x-F.x)<5) {B.x=F.x;}; if(abs(B.y-F.y)<5) {B.y=F.y;}; }; 
    if (pickedF) {if(abs(F.x-B.x)<5) {F.x=B.x;}; if(abs(F.y-B.y)<5) {F.y=B.y;}; }; 
    }
  }

class car {
  float h=40, w=100;                        // car dimensions
  color col;                               // color of car
  pt B=new pt(0,0), F=new pt(w,0);         // front and back points
  float a=0.0;                     // angle and increment
  boolean picked = false;                  // true if being dragged
  car (float px, float py, float pa, color pc) {
    B.x=px; B.y=py; a=pa; col=pc; F.x=px+w; F.y=py; F.turnAround(B,-a);}     // creation
  void paint() {pushMatrix(); translate(B.x,B.y); rotate(a);              // paints car
      noStroke();
      if (picked) {fill(yellow);} else {fill(col);}; rect(w/2,0,w,h); ellipse(0,0,w/7,h*0.95); ellipse(w,0,w/5,h*0.95);      
      fill(240); ellipse(w*0.2,0,w*0.3,h); ellipse(w*0.2+w/3,0,w*0.4,h);
      if (picked) {fill(yellow);} else {fill(col);};  rect(w*0.2+w/6,0,2*w/6,h);    
      popMatrix(); }
  boolean selected() {boolean pic = F.vecTo(mouse()).norm()<w/5; picked=pic; return(pic); }
  void write() {println("Car: a="+a); print(" B="); B.write(); print(" F="); F.write(); }
  void track() {
    pt M=mouse();   
    vec FB = F.vecTo(B); float fb = FB.norm(); vec MB = M.vecTo(B); float mb = MB.norm();
    if (mb<0.0001) {F.setTo(M); B.addVec(FB); } else {F.setTo(M); M.addScaledVec(fb/mb,MB); B.setTo(M); };
    a=angle(I,B.vecTo(F)); 
    }
 void paintDots() {if (!picked) { F.show(20); }; };
  }     
 
void setup(){ size(1000, 800);  createCars (); createStreets(); }

void createCars () {
   C[0] = new car(760,300,2*PI/3,red);  
   C[1] = new car(690,520,3*PI/2,green);  
   C[2] = new car(780,500,3*PI/2,blue); 
   C[3] = new car(450,310,0,grey); 
   C[4] = new car(940,220,PI,grey); 
   C[5] = new car(600,60,PI/2,grey); 
    }
   
void createStreets () {
   S[0] = new street(650,50,650,750,90);
   S[1] = new street(740,50,740,750,90);
   S[2] = new street(50,270,950,270,90);
   S[3] = new street(200,50,200,750,90);
   S[4] = new street(310,620,440,450,70);
   S[5] = new street(290,610,460,720,70);
    }
   
void draw()   {background (255);  rectMode(CENTER);  
  for (int i=0; i<ns; i++) {S[i].paint(); }; 
  stroke(255,245,200);  for (int i=0; i<ns; i++) {S[i].paintLine(); }; 
  for (int i=0; i<nr; i++) {if (C[i].picked) {  fill(200,100,100); } else {fill(100,200,100);}; C[i].paint(); }; 
  if(keyPressed&&(key==' ')) {for (int i=0; i<ns; i++) {S[i].paintDots();};  for (int i=0; i<nr; i++) {C[i].paintDots();};};
  }
    
void mousePressed() {boolean found=false; 
  for (int i=nr-1; i>=0; i--) { if (!found) {if(C[i].selected()) { found=true;}; }; };
  for (int i=ns-1; i>=0; i--) { if (!found) {if(S[i].selected()) { found=true;}; }; };
  } 
void mouseDragged() { 
  for (int i=0; i<nr; i++) { if(C[i].picked) {C[i].track(); }; };
  for (int i=0; i<ns; i++) { if(S[i].picked) {S[i].track(); S[i].snap();  }; };
  }
void mouseReleased() {
  for (int i=0; i<nr; i++) {C[i].picked=false;}; 
  for (int i=0; i<ns; i++) {S[i].pickedF=false; S[i].pickedB=false; S[i].picked=false;}; 
  };
void keyPressed() { if (key=='c') {createCars();}; if (key=='s') {createStreets();}; }